# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit unpacker xdg

DESCRIPTION="GUI for XMR<>BTC atomic swaps (formerly UnstoppableSwap)"
HOMEPAGE="https://eigenwallet.org https://github.com/eigenwallet/core"
SRC_URI="https://github.com/eigenwallet/core/releases/download/${PV}/eigenwallet_${PV}_amd64.deb"
S="${WORKDIR}"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
RESTRICT="mirror strip"

RDEPEND="
	>=sys-libs/glibc-2.39
	dev-libs/glib:2
	net-libs/libsoup:3.0
	net-libs/webkit-gtk:4.1
	sys-devel/gcc:*
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:3
"

QA_PREBUILT="usr/bin/unstoppableswap-gui-rs"

src_prepare() {
	default

	# Upstream ships an empty Categories key
	sed -i 's/^Categories=$/Categories=Network;P2P;Finance;/' \
		usr/share/applications/eigenwallet.desktop || die
}

src_install() {
	dobin usr/bin/unstoppableswap-gui-rs
	dosym unstoppableswap-gui-rs /usr/bin/eigenwallet

	insinto /usr/share
	doins -r usr/share/applications usr/share/icons
}